Skript: Efekty (effects)

Z skript.pl wiki
Skocz do: nawigacja, szukaj


Tą stronę należy dopracować.
Powód: Źle wstawione wzory, brak przykładów wielu efektach, brak segregacji efektów na kategorie.
Po wyeliminowaniu niedoskonałości, proszę usunąć lub edytować szablon {{Dopracować}}.

Odczekiwanie (delay)[edytuj]

Wymagania: Skript od wersji 1.4
Wzór: (wait|halt) [for] %timespan%
Przykład:

command /wait:
    trigger:
        wait 5 minecraft days
        wait 1 second
        wait 1 tick
        broadcast "Komenda /wait odczekała 5 minecraftowych dni, jedną sekundę i 1 tick."
on join:
    wait 10 seconds
    send "Jesteś na serwerze już 10 sekund."

Banowanie (ban)[edytuj]

Wymagania: Skript od wersji 1.4; 2.1.1 - ban reason
Wzory: ban %strings/offlineplayers% [(by reason of|because [of]|on account of|due to) %-string%]
unban %strings/offlineplayers%
ban %players% by IP [(by reason of|because [of]|on account of|due to) %-string%]
unban %players% by IP
IP(-| )ban %players% [(by reason of|because [of]|on account of|due to) %-string%]
(IP(-| )unban|un[-]IP[-]ban) %players%

Przykład:

on quit:
    ban player due to "Zostałeś zbanowany."
command /unban [<offlineplayer>]:
    trigger:
        unban arg 1
        IP unban offlineplayer-argument

Ogłoszenie (broadcast)[edytuj]

Wymagania: Skript od wersji 1.0
Wzór: broadcast %strings% [(to|in) %-worlds%]
Przykład:

command /broadcastsomething:
    trigger:
        broadcast "Wiadomość tą widzą gracze oraz konsola."
on first join:
    broadcast "Przywitajmy nowego gracza: %player%"

Anulowanie wydarzenia (cancel event)[edytuj]

Wymagania: Skript od wersji 1.0
Wzory: cancel [the] event
uncancel [the] event
Przykład:

on break:
    cancel event
    send "Nie możesz niszczyć bloków."
on weather change:
    cancel event
    if number of players is 5: #jeżeli na serwerze jest równe 5 graczy
        uncancel event

Zmiana/ustawianie wartości (set/add/remove/delete/reset)[edytuj]

Wymagania: Skript od wersji 1.0; 2.0 - remove all
Wzory: (add|give) %objects% to %~objects%
increase %~objects% by %objects%
give %~objects% %objects%
set %~objects% to %objects%
remove (all|every) %objects% from %~objects%
(remove|subtract) %objects% from %~objects%
reduce %~objects% by %objects%
(delete|clear) %~objects%
reset %~objects%

Przykład:

increase damage by 10
increase {zmienna.liczbowa} by -10
set {zmienna} to 1
delete loop-entity
give 1 diamond sword to player

on chat:
    add 1 to {wiadomosci.na.chacie.%player%}

Kolorowanie zbroi (colour armour)[edytuj]

Wymagania: Skript od wersji 2.0
Wzory: (dye|colo[u]r|paint) %slots/itemstack% %color%
(dye|colo[u]r|paint) %slots/itemstack% (%number%, %number%, %number%)

Przykład:

dye player's helmet (255, 255, 0)

on jump:
    dye helmet of player red
    wait 1 second
    dye helmet of player blue

Wykonywanie komendy (command)[edytuj]

Wymagania: Skript od wersji 1.0
Wzory: [execute] [the] command %strings% [by %-commandsenders%]
[execute] [the] %commandsenders% command %strings%
(let|make) %commandsenders% execute [[the] command] %strings%

Przykład:

player command "warp spawn"
let player-arg execute "spawn"

on break:
    execute console command "say gracz %player% wykopał %event-block%"

Wyrzucanie przedmiotów na ziemię (drop)[edytuj]

Wymagania: Skript od wersji 1.0
Wzory: drop %itemtypes/experience% [%directions% %locations%]
drop %itemtypes/experience% [%directions% %locations%] without velocity

Przykład:

on mine of stone:
    cancel event
    delete event-block
    drop 1 stone

on death of player:
    drop victim's skull

Zaklinanie przedmiotów (enchant/disenchant)[edytuj]

Wymagania: Skript od wersji 2.0
Wzory: enchant %~itemstack% with %enchantmenttypes%
disenchant %~itemstack%

Przykład:

on mine of stone:
    chance of 1%:
        enchant player's tool with fortune 3

on damage of player:
    disenchant player's helmet

Zakładanie zbroi na ciało (equip)[edytuj]

Wymagania: Skript od wersji 1.0
Wzory: equip [%livingentity%] with %itemtypes%
make %livingentity% wear %itemtypes%

Przykład:

equip player with diamond helmet

on damage:
    if victim is a zombie:
        make victim wear diamond chestplate

Wycofywanie (exit)[edytuj]

Wymagania: Skript od wersji unknown
Wzory: (exit|stop) [trigger]
(exit|stop) [(1|a|the|this)] (section|loop|conditional)
(exit|stop) (section|loop|conditional)s
(exit|stop) all (section|loop|conditional)s

Przykład:

<wpisać>

Tworzenie eksplozji (explosion)[edytuj]

Wymagania: Skript od wersji 1.0
Wzory: [(create|make)] [an] explosion (of|with) (force|strength|power) %number% [%directions% %locations%]
[(create|make)] [a] safe explosion (of|with) (force|strength|power) %number% [%directions% %locations%]
[(create|make)] [a] fake explosion [%directions% %locations%]
[(create|make)] [an] explosion[ ]effect [%directions% %locations%]

Przykład:

on rightclick:
    if player's tool is stick named "BOOM":
        create an explosion of force 10 at the player

on jump:
    make a fake explosion at player

Zadawanie obrażeń/leczenie/naprawianie (damage/heal/repair)[edytuj]

Wymagania: Skript od wersji 1.0
Wzory: damage %slots/livingentities/itemstack% by %number% [heart[s]][ with fake cause %-damagecause%]
heal %livingentities% [by %-number% [heart[s]]]
repair %slots/itemstack% [by %-number%]

Przykład:

damage player by 5 hearts 
heal the player 
repair tool of player

Podpalanie/gaszenie (ignite/extinguish)[edytuj]

Wymagania: Skript od wersji 1.4
Wzory: (ignite|set fire to) %entities% [for %-timespan%]
(set|light) %entities% on fire [for %-timespan%]
extinguish %entities%

Przykład:

command /podpal <player>:
    trigger:
        ignite the player-argument
command /zgasz <player>:
    trigger:
        extinguish the player-argument

Wyrzucanie z serwera (kick)[edytuj]

Wymagania: Skript od wersji 1.0
Wzór: kick %players% [(by reason of|because [of]|on account of|due to) %-string%]
Przykład:

command /kick <player>:
    trigger:
        kick player-argument by reason "Zostałeś wyrzucony."

on join:
    if player is not "Libter":
        kick player due to "Nie jesteś libterem"

Zabijanie (kill)[edytuj]

Wymagania: Skript od wersji 1.0
Wzór: kill %entities%
Przykład:

kill the player 
kill all creepers in the player's world 
kill all endermen, witches and bats

Strzelanie piorunami (lightning)[edytuj]

Wymagania: Skript od wersji 1.4
Wzór: (create|strike) lightning([ ]effect|) %directions% %locations%
Przykład:

on rightclick:
    if player's tool is stick named "Piorun":
        strike lightning at the player
on death:
    strike lightning effect at the victim

Zapisywanie do logów (log)[edytuj]

Wymagania: Skript od wersji 2.0
Wzór: log %strings% [(to|in) [file[s]] %-strings%]
Przykład:

on place of TNT: 
    log "%player% postawił TNT w świecie: %world% na koordynatac: %location of block%" to "tnt.log"
on chat:
    log "%player% > %message%" to "chat.log"

Wysyłanie wiadomości (message)[edytuj]

Wymagania: Skript od wersji 1.0
Wzór: (message|send [message]) %strings% [to %commandsenders%]
Przykład:

on join:
    message "Witaj na serwerze"
on chat:
    send "%player% wysłał coś na czacie" to console

Dawanie/zabieranie op (op/deop)[edytuj]

Wymagania: Skript od wersji 1.0
Wzór: [de[-]]op %offlineplayers%
Przykład:

command /op <player>:
    trigger:
        if player-argument is op:
            deop the player-argument
        else:
            op the player-argument

Otwieranie/zamykanie ekwipunku (open/close Inventory)[edytuj]

Wymagania: Skript od wersji 2.0; 2.1.1 - closing; 2.2-Fixes-V10 - anvil
Wzory: (open|show) (crafting [table]|workbench)|chest|anvil) (view|window|inventory|)|%-inventory%) (to|for) %players%
close [the] inventory [view] (to|of|for) %players%
close %players%'[s] inventory [view]

Przykład:

command /crafting:
    trigger:
        show crafting inventory to player
on join:
     wait 1 tick
     open chest with 6 rows to player

Zatruwanie/odtruwanie (poison/cure)[edytuj]

Wymagania: Skript od wersji 1.3.2
Wzory: poison %livingentities% [for %-timespan%]
(cure|unpoison) %livingentities% [(from|of) poison]

Przykład:

on rightclick:
    if player's tool is stick named "Strzykawka":
        cure the player from poison
on damage:
    if attacker is zombie:
        poison the victim for 20 seconds 

Aplikowanie mikstur (potion effects)[edytuj]

Wymagania: Skript od wersji 2.0
Wzór: apply [potion of] %potioneffecttypes% [potion] [[[of] tier] %-number%] to %livingentities% [for %-timespan%]
Przykład:

apply swiftness 2 to the player
on death of wither:
    apply potion of haste of tier 2 to all players for 99 seconds

Odrzucanie/pchanie (push)[edytuj]

Wymagania: Skript od wersji 1.4.6
Wzór: (push|thrust) %entities% %direction% [(at|with) (speed|velocity|force) %-number%]
Przykład:

push player downwards 
thrust all players upwards with speed 10

Walki między graczami (pvp)[edytuj]

Wymagania: Skript od wersji 1.3.4
Wzory: enable PvP [in %worlds%]
disable PVP [in %worlds%]

Przykład:

command /pvp:
    trigger:

if pvp is true:

            disable PvP
        else:
            enable PvP

Zamienianie tekstu (replace)[edytuj]

Wymagania: Skript od wersji 2.0
Wzory: replace (all|every|) %strings% in %string% with %strings%
replace (all|every|) %strings% with %string% in %strings%

Przykład:

replace all "Zyrafa" with "Giraffe" in message
replace every "Libter" with "nieLibter" in {zmienna}

Zwracanie wartości (return)[edytuj]

Wymagania: Skript od wersji 2.2
Wzór: return %objects%
Przykład:

function add(i: number , d: number) :: number:
   return {_d} + {_i}

Strzyżenie zwierząt (shear)[edytuj]

Wymagania: Skript od wersji 2.0
Wzory: shear %livingentities%
un[-]shear %livingentities%

Przykład:

on rightclick on a sheep holding a sword: 
    shear event-entity

Strzelanie (shoot)[edytuj]

Wymagania: Skript od wersji 1.4
Wzory: shoot %entitydatas% [from %livingentities/locations%] [(at|with) (speed|velocity) %-number%] [%-direction%]
(make|let) %livingentities/locations% shoot %entitydatas% [(at|with) (speed|velocity) %-number%] [%-direction%]

Przykład:

on rightclick:
    make the player shoot a creeper at speed 10
on damage:
     shoot arrow at speed 10 upwards

Przywoływanie istot (spawn)[edytuj]

Wymagania: Skript od wersji 1.0
Wzory: spawn %entitytypes% [%directions% %locations%]
spawn %number% of %entitytypes% [%directions% %locations%]

Przykład:

command /pigspawn:
    trigger:
        spawn pig at player
command /zombies:
    trigger:
     spawn 10 zombies at target block		 

Teleportowanie (teleport)[edytuj]

Wymagania: Skript od wersji 1.0
Wzór: teleport %entities% (to|%direction%) %location%
Przykład:

teleport player to {spawn.location} 
teleport attacker to victim

Przełączanie (toggle)[edytuj]

Wymagania: Skript od wersji 1.4
Wzory:
(close|turn off|de[-]activate) %blocks%
(toggle|switch) [[the] state of] %blocks%
(open|turn on|activate) %blocks%

Przykład:

on leftclick on iron door:
    open event-block
on leftclick on lever:
    toggle state of event-block

Tworzenie drzew (tree)[edytuj]

Wymagania: Skript od wersji 1.0
Wzory: (grow|create|generate) tree [of type %structuretype%] %directions% %locations%
(grow|create|generate) %structuretype% [tree] %directions% %locations%

Przykład:

every 10 seconds:
    loop all players:
        grow tree of type oak at the loop-player

Zasiadanie istot (vehicle)[edytuj]

Wymagania: Skript od wersji 2.0
Wzory: (make|let|force) %entities% [to] (ride|mount) [(in|on)] %entity/entitydatas%
(make|let|force) %entities% [to] (dismount|(dismount|leave) (from|of|) (any|the[ir]|his|her|) vehicle[s])
(eject|dismount) (any|the|) passenger[s] (of|from) %entities%

Przykład:

make player ride a horse
dismount any passenger of attacker

Wyświetlanie efektów wizualnych (play effect)[edytuj]

Wymagania: Skript od wersji 2.1
Wzory: (play|show) %visualeffects% (on|%directions%) %entities/locations% [(to %-players%|in (radius|range) of %number%)]
(play|show) %number% %visualeffects% (on|%directions%) %locations% [(to %-players%|in (radius|range) of %number%)]

Przykład:

on join:
    show smoke at player
on mine:
    play 1 smoke at player to all players

Wersja pętli (loop version)[edytuj]

Wymagania: Skript od wersji unknown (2.2)
Wzór: use[s] (old|new|2.1.2|2.2) loops
Przykład:

use new loops
loop all players:
    send "%loop-player%"