Skript: Komendy

Z skript.pl wiki
Skocz do: nawigacja, szukaj


Wstęp[edytuj]

Wszystkie kody w artykule wymagają oczywiście Skript'a z wersji nieznanej.

Podstawowa komenda[edytuj]

Komendę w Skript definiujemy zaczynając od słowa command a następnie podając nazwę komendy i kończymy dwukropkiem. Następnie należy podać kod który ma się wykonać po wpisaniu komendy. Umieszczamy go pod trigger:

command /ohades:
    trigger:
        # Tu wpisujemy dowolny kod skripta.
        send "ohayou"

Argumenty (arguments)[edytuj]

Wzór: command /nazwakomendy [<argument>]

Spis argumentów:

  • Gracz online (player)> [<player>].
  • Gracz offline (offlineplayer)> [<offlineplayer>].
  • Przedmioty (items)> [<items>].
  • Tekst (text)> [<text>].
  • Liczba rzeczywista (number)> [<number>].
  • Liczba całkowia (integer)> [<integer>].
  • Przedmiot (item)> [<item>].


Przykład:

command /banplayer [<player>] [<number>] [<text>]:
    trigger:
        if player-argument is set:
            if integer-argument is set:
                if text-argument is set:
                    execute console command "ban %player-argument% %integer-argument%d %text-argument%"
                else:
                    message "Wpisz powod!"
                    stop
            else:
                message "Wpisz ilosc dni!"
                stop
        else:
            message "Wpisz nick gracza!"
            stop

Używając [<argument=%wartość domyślna%>] możemy ustawić wartość domyślną gdy argument nie jest wpisany.

command /helloloop <number=3>:
    trigger:
        loop argument 1 times:
            send "HELLO WORLD #%loop-value%."

Opis (description)[edytuj]

Wzór: description: (opis)
Przykład:

command /opis:
    description: Jest to komenda testowa.
    trigger:
        #dalszy kod

Stosowanie (usage)[edytuj]

Wzór: usage: (stosowanie)
Przykład:

command /uzyj:
    usage: Uzyj: /uzyj
    trigger:
        #dalszy kod

Uprawnienie (permission)[edytuj]

Wzór: permission: (uprawnienie)
Przykład:

command /uprawnienie:
    permission: Uprawnienie.use
    trigger:
        #dalszy kod

Komunikat o braku uprawnień (permission message)[edytuj]

Wzór: permission message: (wiadomosc)
Przykład:

command /perm_message:
    permission message: Nie masz uprawnienia! 
    trigger: 
        #dalszy kod

Wykonawca (executable by)[edytuj]

Wzór: executable by: (wykonawca)

Wykonawcą może być:

  • players players.
  • console console.
  • players and console players and console.

Przykład:

command /executable_by:
    executable by: players
    trigger: 
        #dalszy kod

Skróty komend (aliases)[edytuj]

Wzór: aliases: (komenda)
Przykład:

command /aliases:
    aliases: alias, aliascommand
    trigger:
        #dalszy kod

command /nazwa_komendy [<argument>]:
    description: To jest przykladowa komenda.
    usage: Uzyj /nazwa_komendy <argument>
    permission: Nazwa_komendy.use
    permission message: Nie posiadasz uprawnienia!
    executable by: players
    aliases: commandname, namecommand
    trigger:
        #Dalsza czesc kodu